qid string | nlq string | sparql string |
|---|---|---|
ds5 | Provide a summary of the presence of the core parameter load capability (1.1.1.1.2.4) across all tracks per member state. | PREFIX era: <http://data.europa.eu/949/>
SELECT DISTINCT ?inCountry ?numTotalTracks ?numTracksWithLoadCapability ?numTracksWithoutLoadCapability
WHERE {
{
SELECT DISTINCT ?inCountry (COUNT(DISTINCT ?track) AS ?numTotalTracks)
WHERE {
?track a era:Track .
?sectionOfLine era:track ?track .
?sectionOfLine a era:SectionOfLine .
?sectionOfLine era:inCountry ?inCountry
}
}
OPTIONAL {
SELECT DISTINCT ?inCountry (COUNT(DISTINCT ?track) AS ?numTracksWithLoadCapability)
WHERE {
?track a era:Track .
?track era:trackLoadCapability ?loadCapability .
?sectionOfLine era:track ?track .
?sectionOfLine a era:SectionOfLine .
?sectionOfLine era:inCountry ?inCountry
}
}
OPTIONAL {
SELECT DISTINCT ?inCountry (COUNT(DISTINCT ?track) AS ?numTracksWithoutLoadCapability)
WHERE {
?track a era:Track .
?sectionOfLine era:track ?track .
?sectionOfLine a era:SectionOfLine .
?sectionOfLine era:inCountry ?inCountry
FILTER NOT EXISTS { ?track era:trackLoadCapability ?loadCapability }
}
}
} |
ds6 | Provide a summary of sections of lines and tracks where the core parameter load capability (1.1.1.1.2.4) does not appear (example with Spain). | PREFIX era: <http://data.europa.eu/949/>
SELECT DISTINCT ?inCountry ?sectionOfLine ?trackWithoutLoadCapability
WHERE {
VALUES ?inCountry { <http://publications.europa.eu/resource/authority/country/ESP> } .
?trackWithoutLoadCapability a era:Track .
?sectionOfLine era:track ?trackWithoutLoadCapability .
?sectionOfLine a era:SectionOfLine .
?sectionOfLine era:inCountry ?inCountry .
FILTER NOT EXISTS {
?trackWithoutLoadCapability era:trackLoadCapability ?loadcapability .
}
} |
ds9 | Provide all tracks where core parameters do not appear (example with Spain). | PREFIX era: <http://data.europa.eu/949/>
SELECT DISTINCT ?track ?p
WHERE {
VALUES ?inCountry {<http://publications.europa.eu/resource/authority/country/ESP>} .
VALUES ?p {era:wheelSetGauge era:gaugingProfile era:railInclination era:eddyCurrentBraking era:magneticBraking era:minimumWheelDiameter era:minimumHorizontalRadius era:protectionLegacySystem era:legacyRadioSystem era:maximumTrainDeceleration era:gradientProfile era:hasHotAxleBoxDetector era:hasSevereWeatherConditions era:trackLoadCapability era:maximumBrakingDistance era:maximumPermittedSpeed era:hasAdditionalBrakingInformation era:temperatureRange era:cantDeficiency}
?track a era:Track .
?sectionOfLine era:track ?track .
?sectionOfLine a era:SectionOfLine .
?sectionOfLine era:inCountry ?inCountry .
?p era:rinfIndex ?rinfIndex .
FILTER NOT EXISTS { ?track ?p ?propertyValue . }
}
ORDER BY ?track
LIMIT 1000 |
ds10 | Provide a summary of the presence of core parameters applicable to sections of line per member state. | PREFIX era: <http://data.europa.eu/949/>
SELECT DISTINCT ?p ?inCountry ?numTotalSOLs ?numSOLsWithPropertyAsCoreParameter ?numSOLsWithoutPropertyAsCoreParameter
WHERE {
VALUES ?p { era:length }
{
SELECT DISTINCT ?inCountry (COUNT(DISTINCT ?sectionOfLine) AS ?numTotalSOLs)
WHERE {
?sectionOfLine a era:SectionOfLine .
?sectionOfLine era:inCountry ?inCountry .
}
}
OPTIONAL {
SELECT DISTINCT ?inCountry ?p (COUNT(DISTINCT ?sectionOfLine) AS ?numSOLsWithPropertyAsCoreParameter)
WHERE {
VALUES ?p { era:length }
?sectionOfLine a era:SectionOfLine .
?sectionOfLine ?p ?propertyValue .
?sectionOfLine era:inCountry ?inCountry .
}
}
OPTIONAL {
SELECT DISTINCT ?inCountry ?p (COUNT(DISTINCT ?sectionOfLine) AS ?numSOLsWithoutPropertyAsCoreParameter)
WHERE {
VALUES ?p { era:length }
?sectionOfLine a era:SectionOfLine .
?sectionOfLine era:inCountry ?inCountry .
FILTER NOT EXISTS {
?sectionOfLine ?p ?propertyValue .
VALUES ?p { era:length }
}
}
}
}
ORDER BY ?p ?inCountry |
ds11 | Provide all sections of line where core parameters do not appear (example with Spain). | PREFIX era: <http://data.europa.eu/949/>
SELECT DISTINCT ?sectionOfLine ?p ?rinfIndex
WHERE {
VALUES ?inCountry { <http://publications.europa.eu/resource/authority/country/ESP> } .
VALUES ?p { era:length }
?sectionOfLine a era:SectionOfLine .
?sectionOfLine era:inCountry ?inCountry.
?p era:rinfIndex ?rinfIndex
FILTER NOT EXISTS {
?sectionOfLine ?p ?propertyValue
}
}
ORDER BY ?sectionOfLine LIMIT 1000 |
ds12 | Provide a summary of the presence of core parameters applicable to tunnels per member state. | PREFIX era: <http://data.europa.eu/949/>
SELECT DISTINCT ?p ?inCountry ?numTotalEntities ?numEntitiesWithPropertyAsCoreParameter ?numEntitiesWithoutPropertyAsCoreParameter
WHERE {
VALUES ?p { era:length era:rollingStockFireCategory era:tunnelIdentification }
{
SELECT DISTINCT ?inCountry (COUNT(DISTINCT ?entity) AS ?numTotalEntities)
WHERE {
?entity a era:Tunnel .
?entity era:inCountry ?inCountry
}
}
OPTIONAL {
SELECT DISTINCT ?inCountry ?p (COUNT(DISTINCT ?entity) AS ?numEntitiesWithPropertyAsCoreParameter)
WHERE {
VALUES ?p { era:length era:rollingStockFireCategory era:tunnelIdentification }
?entity a era:Tunnel .
?entity ?p ?propertyValue .
?entity era:inCountry ?inCountry
}
}
OPTIONAL {
SELECT DISTINCT ?inCountry ?p (COUNT(DISTINCT ?entity) AS ?numEntitiesWithoutPropertyAsCoreParameter)
WHERE {
VALUES ?p { era:length era:rollingStockFireCategory era:tunnelIdentification }
?entity a era:Tunnel .
?entity era:inCountry ?inCountry
FILTER NOT EXISTS { ?entity ?p ?propertyValue }
}
}
}
ORDER BY ?p ?inCountry |
ds13 | Provide all tunnels where core parameters do not appear (example with Spain). | PREFIX era: <http://data.europa.eu/949/>
SELECT DISTINCT ?entity ?p ?rinfIndex
WHERE {
VALUES ?inCountry { <http://publications.europa.eu/resource/authority/country/ESP> }
VALUES ?p { era:length era:rollingStockFireCategory era:tunnelIdentification }
?entity a era:Tunnel .
?entity era:inCountry ?inCountry .
?p era:rinfIndex ?rinfIndex .
FILTER NOT EXISTS { ?entity ?p ?propertyValue }
}
ORDER BY ?entity
LIMIT 1000 |
ds14 | Provide a summary of the presence of core parameters applicable to sidings per member state. | PREFIX era: <http://data.europa.eu/949/>
SELECT DISTINCT ?p ?inCountry ?numTotalEntities ?numEntitiesWithPropertyAsCoreParameter ?numEntitiesWithoutPropertyAsCoreParameter
WHERE {
VALUES ?p {era:length era:minimumHorizontalRadius}
{
SELECT DISTINCT ?inCountry (COUNT(DISTINCT ?entity) AS ?numTotalEntities)
WHERE {
?entity a era:Siding .
?op a era:OperationalPoint .
?op era:siding ?entity .
?op era:inCountry ?inCountry
}
}
OPTIONAL {
SELECT DISTINCT ?inCountry ?p (COUNT(DISTINCT ?entity) AS ?numEntitiesWithPropertyAsCoreParameter)
WHERE {
VALUES ?p {era:length era:minimumHorizontalRadius}
?entity a era:Siding .
?entity ?p ?propertyValue .
?op a era:OperationalPoint .
?op era:siding ?entity .
?op era:inCountry ?inCountry
}
}
OPTIONAL {
SELECT DISTINCT ?inCountry ?p (COUNT(DISTINCT ?entity) AS ?numEntitiesWithoutPropertyAsCoreParameter)
WHERE {
VALUES ?p {era:length era:minimumHorizontalRadius}
?entity a era:Siding .
?op a era:OperationalPoint .
?op era:siding ?entity .
?op era:inCountry ?inCountry
FILTER NOT EXISTS {?entity ?p ?propertyValue }
}
}
} ORDER BY ?p ?inCountry |
ds15 | Provide all the sidings where core parameters do not appear (example with Spain). | PREFIX era: <http://data.europa.eu/949/>
SELECT DISTINCT ?entity ?p ?rinfIndex
WHERE {
VALUES ?inCountry { <http://publications.europa.eu/resource/authority/country/ESP> } .
VALUES ?p { era:length era:minimumHorizontalRadius }
?entity a era:Siding .
?op a era:OperationalPoint .
?op era:siding ?entity .
?op era:inCountry ?inCountry .
?p era:rinfIndex ?rinfIndex .
FILTER NOT EXISTS {
?entity ?p ?propertyValue
}
}
ORDER BY ?entity
LIMIT 1000 |
ds16 | Provide a summary of the presence of core parameters applicable to operational points per member state. | PREFIX era: <http://data.europa.eu/949/>
SELECT DISTINCT ?p ?inCountry ?numTotalEntities ?numEntitiesWithPropertyAsCoreParameter ?numEntitiesWithoutPropertyAsCoreParameter
WHERE {
VALUES ?p { era:lineReference }
{
SELECT DISTINCT ?inCountry (COUNT(DISTINCT ?entity) AS ?numTotalEntities)
WHERE {
?entity a era:OperationalPoint .
?entity era:inCountry ?inCountry
}
}
OPTIONAL {
SELECT DISTINCT ?inCountry ?p (COUNT(DISTINCT ?entity) AS ?numEntitiesWithPropertyAsCoreParameter)
WHERE {
?entity a era:OperationalPoint .
?entity era:inCountry ?inCountry .
?entity ?p ?propertyValue
}
}
OPTIONAL {
SELECT DISTINCT ?inCountry ?p (COUNT(DISTINCT ?entity) AS ?numEntitiesWithoutPropertyAsCoreParameter)
WHERE {
?entity a era:OperationalPoint .
?entity era:inCountry ?inCountry .
FILTER NOT EXISTS { ?entity ?p ?propertyValue }
}
}
}
ORDER BY ?p ?inCountry |
ds17 | Provide all operational points where core parameters do not appear (example with Spain). | PREFIX era: <http://data.europa.eu/949/>
SELECT DISTINCT ?entity ?p ?rinfIndex
WHERE {
VALUES ?inCountry {<http://publications.europa.eu/resource/authority/country/ESP>} .
VALUES ?p {era:lineReference}
?entity a era:OperationalPoint .
?entity era:inCountry ?inCountry .
?p era:rinfIndex ?rinfIndex .
FILTER NOT EXISTS {?entity ?p ?propertyValue}
}
ORDER BY ?entity
LIMIT 1000 |
ds18 | Provide a summary of the presence of core parameters applicable to platforms per member state. | PREFIX era: <http://data.europa.eu/949/>
SELECT DISTINCT ?p ?inCountry ?numTotalTracks ?numTracksWithPropertyAsCoreParameter ?numTracksWithoutPropertyAsCoreParameter
WHERE {
VALUES ?p {era:platformId era:length era:platformHeight}
{
SELECT DISTINCT ?inCountry (COUNT(DISTINCT ?track) AS ?numTotalTracks)
WHERE {
?entity a era:Platform .
?track a era:Track.
?track era:platform ?entity .
?sectionOfLine era:track ?track .
?sectionOfLine era:inCountry ?inCountry
}
}
OPTIONAL
{
SELECT DISTINCT ?inCountry ?p (COUNT(DISTINCT ?track) AS ?numTracksWithPropertyAsCoreParameter)
WHERE {
?entity a era:Platform .
?track a era:Track.
?track era:platform ?entity .
?sectionOfLine era:track ?track .
?sectionOfLine era:inCountry ?inCountry .
?entity ?p ?propertyValue .
}
}
OPTIONAL
{
SELECT DISTINCT ?inCountry ?p (COUNT(DISTINCT ?track) AS ?numTracksWithoutPropertyAsCoreParameter)
WHERE {
?entity a era:Platform .
?track a era:Track.
?track era:platform ?entity .
?sectionOfLine era:track ?track .
?sectionOfLine era:inCountry ?inCountry
FILTER NOT EXISTS { ?entity ?p ?propertyValue . }
}
}
}
ORDER BY ?p ?inCountry |
ds19 | Provide all platforms where core parameters do not appear (example with Spain). | PREFIX era: <http://data.europa.eu/949/>
SELECT DISTINCT ?entity ?p ?rinfIndex
WHERE {
VALUES ?inCountry {<http://publications.europa.eu/resource/authority/country/ESP>} .
VALUES ?p {era:platformId era:length era:platformHeight}
?entity a era:Platform .
?track a era:Track.
?track era:platform ?entity .
?sectionOfLine era:track ?track .
?sectionOfLine era:inCountry ?inCountry .
?p era:rinfIndex ?rinfIndex .
FILTER NOT EXISTS {?entity ?p ?propertyValue}
} ORDER BY ?entity LIMIT 1000 |
ds20 | Provide a summary of the presence of core parameters applicable to tracks' contact line systems per member state, without checking parameter applicability. | PREFIX era: <http://data.europa.eu/949/>
SELECT DISTINCT ?p ?inCountry ?numTotalTracks ?numTracksWithPropertyAsCoreParameter ?numTracksWithoutPropertyAsCoreParameter
WHERE {
VALUES ?p { era:energySupplySystem era:contactLineSystemType }
{
SELECT DISTINCT ?inCountry (COUNT(DISTINCT ?track) AS ?numTotalTracks)
WHERE {
?track a era:Track .
?sectionOfLine era:track ?track .
?sectionOfLine a era:SectionOfLine .
?sectionOfLine era:inCountry ?inCountry
}
}
OPTIONAL {
SELECT DISTINCT ?inCountry ?p (COUNT(DISTINCT ?track) AS ?numTracksWithPropertyAsCoreParameter)
WHERE {
VALUES ?p { era:energySupplySystem era:contactLineSystemType }
?track a era:Track .
?track era:contactLineSystem ?cls .
?cls ?p ?propertyValue .
?sectionOfLine era:track ?track .
?sectionOfLine a era:SectionOfLine .
?sectionOfLine era:inCountry ?inCountry
}
}
OPTIONAL {
SELECT DISTINCT ?inCountry ?p (COUNT(DISTINCT ?track) AS ?numTracksWithoutPropertyAsCoreParameter)
WHERE {
VALUES ?p { era:energySupplySystem era:contactLineSystemType }
?track a era:Track .
?track era:contactLineSystem ?cls .
?sectionOfLine era:track ?track .
?sectionOfLine a era:SectionOfLine .
?sectionOfLine era:inCountry ?inCountry
FILTER NOT EXISTS { ?cls ?p ?propertyValue . }
}
}
}
ORDER BY ?p ?inCountry |
ds21 | Provide a summary of the presence of core parameters applicable to tracks' contact line systems per member state, checking parameter applicability. | PREFIX era: <http://data.europa.eu/949/>
SELECT DISTINCT ?p ?inCountry ?numTotalTracks ?numTracksWithPropertyAsCoreParameter ?numTracksWithoutPropertyAsCoreParameter
WHERE {
VALUES ?p { era:energySupplySystem era:contactLineSystemType }
{
SELECT DISTINCT ?inCountry (COUNT(DISTINCT ?track) AS ?numTotalTracks)
WHERE {
?track a era:Track .
?sectionOfLine era:track ?track .
?sectionOfLine a era:SectionOfLine .
?sectionOfLine era:inCountry ?inCountry .
FILTER NOT EXISTS { ?track era:notApplicable ?p }
}
}
OPTIONAL {
SELECT DISTINCT ?inCountry ?p (COUNT(DISTINCT ?track) AS ?numTracksWithPropertyAsCoreParameter)
WHERE {
?track a era:Track .
?track era:contactLineSystem ?cls .
?cls ?p ?propertyValue .
?sectionOfLine era:track ?track .
?sectionOfLine a era:SectionOfLine .
?sectionOfLine era:inCountry ?inCountry .
}
}
OPTIONAL {
SELECT DISTINCT ?inCountry ?p (COUNT(DISTINCT ?track) AS ?numTracksWithoutPropertyAsCoreParameter)
WHERE {
?track a era:Track .
?track era:contactLineSystem ?cls .
?sectionOfLine era:track ?track .
?sectionOfLine a era:SectionOfLine .
?sectionOfLine era:inCountry ?inCountry .
FILTER NOT EXISTS { ?cls ?p ?propertyValue . }
}
}
}
ORDER BY ?p ?inCountry |
ds22 | Provide all the tracks and contact line systems where core parameters do not appear, without checking parameter applicability (example with Spain). | PREFIX era: <http://data.europa.eu/949/>
SELECT DISTINCT ?track ?cls ?p #?rinfIndex
WHERE {
VALUES ?inCountry {<http://publications.europa.eu/resource/authority/country/ESP>} .
VALUES ?p {era:energySupplySystem era:contactLineSystemType}
?track a era:Track .
?track era:contactLineSystem ?cls .
?sectionOfLine era:track ?track .
?sectionOfLine a era:SectionOfLine .
?sectionOfLine era:inCountry ?inCountry.
?p era:rinfIndex ?rinfIndex .
FILTER NOT EXISTS {?cls ?p ?propertyValue .}
}
ORDER BY ?track ?cls
LIMIT 1000 |
ds23 | Provide all the tracks and contact line systems where core parameters do not appear, checking parameter applicability (example with Spain). | PREFIX era: <http://data.europa.eu/949/>
SELECT DISTINCT ?track ?cls ?p
WHERE {
VALUES ?inCountry {<http://publications.europa.eu/resource/authority/country/ESP>} .
VALUES ?p {era:energySupplySystem era:contactLineSystemType}
?track a era:Track .
?track era:contactLineSystem ?cls .
FILTER NOT EXISTS {?track era:notApplicable ?p}.
?sectionOfLine era:track ?track .
?sectionOfLine a era:SectionOfLine .
?sectionOfLine era:inCountry ?inCountry.
?p era:rinfIndex ?rinfIndex .
FILTER NOT EXISTS {?cls ?p ?propertyValue .}
}
ORDER BY ?track ?cls
LIMIT 1000 |
ds24 | Provide a summary of the presence of core parameters applicable to tracks' train detection systems per member state. | PREFIX era: <http://data.europa.eu/949/>
SELECT DISTINCT ?p ?inCountry ?numTotalTracks ?numTracksWithPropertyAsCoreParameter ?numTracksWithoutPropertyAsCoreParameter
WHERE {
VALUES ?p {era:trainDetectionSystemType}
{
SELECT DISTINCT ?inCountry (COUNT(DISTINCT ?track) AS ?numTotalTracks)
WHERE {
?track a era:Track .
?sectionOfLine era:track ?track .
?sectionOfLine a era:SectionOfLine .
?sectionOfLine era:inCountry ?inCountry
}
} OPTIONAL
{
SELECT DISTINCT ?inCountry ?p (COUNT(DISTINCT ?track) AS ?numTracksWithPropertyAsCoreParameter)
WHERE {
VALUES ?p {era:trainDetectionSystemType}
?track a era:Track .
?track era:trainDetectionSystem ?tds .
?tds ?p ?propertyValue .
?sectionOfLine era:track ?track .
?sectionOfLine a era:SectionOfLine .
?sectionOfLine era:inCountry ?inCountry
}
} OPTIONAL
{
SELECT DISTINCT ?inCountry ?p (COUNT(DISTINCT ?track) AS ?numTracksWithoutPropertyAsCoreParameter)
WHERE {
VALUES ?p {era:trainDetectionSystemType}
?track a era:Track .
?track era:trainDetectionSystem ?tds .
?sectionOfLine era:track ?track .
?sectionOfLine a era:SectionOfLine .
?sectionOfLine era:inCountry ?inCountry
FILTER NOT EXISTS { ?tds ?p ?propertyValue . }
}
}
}
ORDER BY ?p ?inCountry |
ds25 | Provide all the tracks and train detection systems where core parameters do not appear (example with Spain). | PREFIX era: <http://data.europa.eu/949/>
SELECT DISTINCT ?track ?tds ?p
WHERE {
VALUES ?inCountry { <http://publications.europa.eu/resource/authority/country/ESP> }
VALUES ?p { era:trainDetectionSystemType }
?track a era:Track .
?track era:trainDetectionSystem ?tds .
?sectionOfLine era:track ?track .
?sectionOfLine a era:SectionOfLine .
?sectionOfLine era:inCountry ?inCountry .
?p era:rinfIndex ?rinfIndex .
FILTER NOT EXISTS {
?tds ?p ?propertyValue
}
}
ORDER BY ?track ?tds
LIMIT 1000 |
ds26 | Number of tracks, per country, that are not TSI compliant. | PREFIX era: <http://data.europa.eu/949/>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
SELECT DISTINCT ?country (COUNT(DISTINCT ?track) AS ?countTracks)
WHERE {
?sectionOfLine a era:SectionOfLine .
?sectionOfLine era:inCountry ?country .
?sectionOfLine era:track ?track .
?track a era:Track .
?track era:hasTSITrainDetection "false"^^xsd:boolean
}
ORDER BY ?country |
ds27 | Number of tracks, per country, whose associated train detection systems are not TSI compliant. | PREFIX era: <http://data.europa.eu/949/>
SELECT DISTINCT ?country ?p (COUNT(DISTINCT ?track) AS ?numberTracks)
WHERE {
?sectionOfLine a era:SectionOfLine .
?sectionOfLine era:inCountry ?country .
?sectionOfLine era:track ?track .
?track a era:Track .
?track era:trainDetectionSystem ?tds .
?tds a era:TrainDetectionSystem .
VALUES ?p {
era:tsiCompliantCompositeBrakeBlocks
era:tsiCompliantFerromagneticWheel
era:tsiCompliantMaxImpedanceWheelset
era:tsiCompliantMetalConstruction
era:tsiCompliantMetalFreeSpace
era:tsiCompliantRSTShuntImpedance
era:tsiCompliantSandCharacteristics
era:tsiCompliantSanding
era:tsiCompliantShuntDevices
}
?tds ?p <http://data.europa.eu/949/concepts/tsi-compliances/rinf/not_TSI_compliant>
}
ORDER BY ?country ?p |
ds28 | Types of gauging profiles of tracks in neighbouring countries to Ukraine. | PREFIX era: <http://data.europa.eu/949/>
PREFIX country: <http://publications.europa.eu/resource/authority/country/>
SELECT DISTINCT ?country ?gprofile
WHERE {
VALUES ?country { country:HUN country:ROU country:SVK country:POL }
?sectionOfLine a era:SectionOfLine .
?sectionOfLine era:inCountry ?country .
?sectionOfLine era:track ?track .
?track a era:Track .
?track era:gaugingProfile ?gprofile .
}
ORDER BY ?country |
ds29 | Identify unreachable Operational Points. | PREFIX era: <http://data.europa.eu/949/>
PREFIX era-dir: <http://data.europa.eu/949/concepts/track-running-directions/rinf/>
SELECT DISTINCT ?op ?uopid ?country
WHERE {
# Main OP to be analyzed
?op era:inCountry ?country;
era:uopid ?uopid.
# Main SoL to be analyzed with tracks only departing from the main OP
?sol a era:SectionOfLine;
era:track [ era:trackDirection era-dir:10 ];
era:opStart ?op.
# Condition: There are no other tracks in the main SoL with arriving directions
FILTER NOT EXISTS {
?sol era:track [ era:trackDirection era-dir:20 ]
}
FILTER NOT EXISTS {
?sol era:track [ era:trackDirection era-dir:30 ]
}
# Condition: There are no SoLs also departing on the main OP with tracks having arriving directions
FILTER NOT EXISTS {
?sol1 era:opStart ?op;
era:track [ era:trackDirection era-dir:20 ]
}
FILTER NOT EXISTS {
?sol1 era:opStart ?op;
era:track [ era:trackDirection era-dir:30 ]
}
# Condition: There are no other SoLs arriving on the main OP with tracks having arriving directions
FILTER NOT EXISTS {
?sol2 era:opEnd ?op;
era:track [ era:trackDirection era-dir:10 ]
}
FILTER NOT EXISTS {
?sol2 era:opEnd ?op;
era:track [ era:trackDirection era-dir:30 ]
}
}
ORDER BY ?op ?country |
ds30 | Identify sink Operational Points. | PREFIX era: <http://data.europa.eu/949/>
PREFIX era-dir: <http://data.europa.eu/949/concepts/track-running-directions/rinf/>
SELECT DISTINCT ?op ?uopid ?country
WHERE {
# Main OP to be analyzed
?op era:inCountry ?country;
era:uopid ?uopid.
# Main SoL to be analyzed with tracks only departing from the main OP
?sol a era:SectionOfLine;
era:track [ era:trackDirection era-dir:10 ];
era:opStart ?op.
# Condition: There are no other tracks in the main SoL with arriving directions
FILTER NOT EXISTS {
?sol era:track [ era:trackDirection era-dir:20 ]
}
FILTER NOT EXISTS {
?sol era:track [ era:trackDirection era-dir:30 ]
}
# Condition: There are no SoLs also departing on the main OP with tracks having arriving directions
FILTER NOT EXISTS {
?sol1 era:opStart ?op;
era:track [ era:trackDirection era-dir:20 ]
}
FILTER NOT EXISTS {
?sol1 era:opStart ?op;
era:track [ era:trackDirection era-dir:30 ]
}
# Condition: There are no other SoLs arriving on the main OP with tracks having arriving directions
FILTER NOT EXISTS {
?sol2 era:opEnd ?op;
era:track [ era:trackDirection era-dir:10 ]
}
FILTER NOT EXISTS {
?sol2 era:opEnd ?op;
era:track [ era:trackDirection era-dir:30 ]
}
}
ORDER BY ?op ?country |
ds31 | Identify disconnected Operational Points. | PREFIX era: <http://data.europa.eu/949/>
PREFIX era-dir: <http://data.europa.eu/949/concepts/track-running-directions/>
PREFIX era-op-types: <http://data.europa.eu/949/concepts/op-types/rinf/>
SELECT DISTINCT ?op ?uopid ?country
WHERE {
# Main OP to be analyzed
?op era:inCountry ?country;
era:uopid ?uopid .
# Condition: Operational point is not a border point
FILTER NOT EXISTS {
?op era:opType era-op-types:90 # border point
}
# Condition: There are no other SoLs reaching the OP
FILTER NOT EXISTS {
?sol era:opEnd ?op
}
# Condition: There are no other SoLs leaving from the OP
FILTER NOT EXISTS {
?sol era:opStart ?op
}
}
ORDER BY ?op ?country |
ds32 | Query that allows generating INSPIRE-related data according to the INSPIRE ontologies. | PREFIX era: <http://data.europa.eu/949/>
PREFIX inspire: <http://inspire.ec.europa.eu/ont/net#>
CONSTRUCT {
?track a inspire:Link;
inspire:Link.startNode ?startOP;
inspire:Link.endNode ?endOP.
?startOP a inspire:Node.
?endOP a inspire:Node.
}
WHERE {
?track a era:Track;
^era:track [
era:opStart ?startOP;
era:opEnd ?endOP;
era:inCountry <http://publications.europa.eu/resource/authority/country/BEL>
].
} |
ds33 | Determine the compliance of tracks of a specific section of line, with the High Speed Load Model (HSLM) - era:highSpeedLoadModelCompliance, RINF index 1.1.1.1.2.4.2. | PREFIX era: <http://data.europa.eu/949/>
SELECT DISTINCT *
WHERE {
?sol a era:SectionOfLine .
?sol era:opStart ?op_start .
?op_start era:opName ?op_startName .
?sol era:opEnd ?op_end .
?op_end era:opName ?op_endName .
FILTER (regex(?op_startName, "Dendermonde")) .
FILTER (regex(?op_endName, "Zele")) .
?sol era:track ?track .
?track era:trackId ?trackId .
OPTIONAL {
?track era:highSpeedLoadModelCompliance ?highSpeedLoadModelCompliance
}
} |
ds34 | Classification of a specific section of line according to the INF TSI - era:lineCategory, RINF index 1.2.1.0.2.2. | PREFIX era: <http://data.europa.eu/949/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
SELECT DISTINCT *
{
?sol a era:SectionOfLine .
?sol era:opStart ?op_start .
?sol era:opEnd ?op_end .
?op_start era:opName ?op_startName .
?op_end era:opName ?op_endName .
FILTER (regex(?op_startName, "Dendermonde")) .
FILTER (regex(?op_endName, "Zele")) .
?sol era:lineNationalId ?x .
?sol era:track ?track .
?track era:lineCategory [ skos:prefLabel ?lineCategory ] .
} |
ds35 | Number of tracks for a specific section of line. | PREFIX era: <http://data.europa.eu/949/>
SELECT (COUNT(DISTINCT ?track) AS ?tracks)
WHERE {
?sol a era:SectionOfLine .
?sol era:opStart ?op_start .
?op_start era:opName ?op_startName .
?sol era:opEnd ?op_end .
?op_end era:opName ?op_endName .
FILTER (regex(?op_startName, "Dendermonde")) .
FILTER (regex(?op_endName, "Zele")).
?sol era:track ?track .
} |
ds36 | Type of contact line systems of the tracks in a specific section of line. | PREFIX era: <http://data.europa.eu/949/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
SELECT DISTINCT *
{
?sol a era:SectionOfLine.
?sol era:opStart ?op_start.
?op_start era:opName ?op_startName .
?sol era:opEnd ?op_end.
?op_end era:opName ?op_endName .
FILTER (regex(?op_startName, "Dendermonde")) .
FILTER (regex(?op_endName, "Zele")).
?sol era:track ?track .
?track era:trackId ?trackId .
?track era:contactLineSystem ?cls .
?cls era:contactLineSystemType [skos:prefLabel ?clstype] .
} |
ds37 | Wheel set gauge of the tracks in a specific section of line. | PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX era: <http://data.europa.eu/949/>
SELECT DISTINCT *
WHERE {
?sol a era:SectionOfLine.
?sol era:opStart ?op_start.
?op_start era:opName ?op_startName .
?sol era:opEnd ?op_end.
?op_end era:opName ?op_endName .
FILTER (regex(?op_startName,"Dendermonde")) .
FILTER (regex(?op_endName,"Zele")).
?sol era:track ?track .
?track era:wheelSetGauge [skos:prefLabel ?wheelSetGauge] .
} |
ds38 | Energy supply system associated to the tracks in a specific section of line. | PREFIX era: <http://data.europa.eu/949/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
SELECT DISTINCT *
WHERE {
?sol a era:SectionOfLine .
?sol era:opStart ?op_start .
?op_start era:opName ?op_startName .
?sol era:opEnd ?op_end .
?op_end era:opName ?op_endName .
FILTER (regex(?op_startName, "Dendermonde")) .
FILTER (regex(?op_endName, "Zele")) .
?sol era:track ?track .
?track era:trackId ?trackId .
?track era:contactLineSystem ?cls .
?cls era:energySupplySystem [ skos:prefLabel ?energySupplySystem ] .
} |
ds39 | ERTMS / ETCS application level of tracks in a specific section of line, which expresses the possible operating relationships between track and train. | PREFIX era: <http://data.europa.eu/949/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
SELECT DISTINCT *
{
?sol a era:SectionOfLine .
?sol era:opStart ?op_start .
?op_start era:opName ?op_startName .
?sol era:opEnd ?op_end .
?op_end era:opName ?op_endName .
FILTER (regex(?op_startName, "Dendermonde")) .
FILTER (regex(?op_endName, "Zele")) .
?sol era:track ?track .
?track era:trackId ?trackId .
?track era:etcsLevel ?etcsLevel .
?etcsLevelURI era:etcsLevelType [ skos:prefLabel ?etcsLevelType ] .
FILTER (uri(?etcsLevel) = ?etcsLevelURI)
} |
ds40 | ETCS baseline installed in the tracks of a specific section of line. | PREFIX era: <http://data.europa.eu/949/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
SELECT DISTINCT *
WHERE {
?sol a era:SectionOfLine .
?sol era:opStart ?op_start .
?op_start era:opName ?op_startName .
FILTER (regex(?op_startName, "Dendermonde")) .
?sol era:opEnd ?op_end .
?op_end era:opName ?op_endName .
FILTER (regex(?op_endName, "Zele")) .
?sol era:track ?track .
?track era:trackId ?trackId .
?track era:etcsLevel ?etcsLevel .
OPTIONAL {
?etcsLevelURI era:etcsBaseline [ skos:prefLabel ?etcsBaseline ] .
FILTER (uri(?etcsLevel) = ?etcsLevelURI)
}
} |
ds41 | Location of particular points requiring specific checks due to deviations from gauging, for tracks in a specific section of line. | PREFIX era: <http://data.europa.eu/949/>
SELECT DISTINCT *
{
?sol a era:SectionOfLine .
?sol era:opStart ?op_start .
?op_start era:opName ?op_startName .
FILTER (regex(?op_startName, "Dendermonde"))
?sol era:opEnd ?op_end .
?op_end era:opName ?op_endName .
FILTER (regex(?op_endName, "Zele"))
?sol era:track ?track .
?track era:trackId ?trackId .
OPTIONAL { ?track era:gaugingCheckLocation ?location . }
} |
ds42 | Combined transport profile for semi-trailers, for tracks in a specific section of line. | PREFIX era: <http://data.europa.eu/949/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
SELECT DISTINCT *
{
?sol a era:SectionOfLine.
?sol era:opStart ?op_start.
?op_start era:opName ?op_startName.
FILTER (regex(?op_startName, "Dendermonde")).
?sol era:opEnd ?op_end.
?op_end era:opName ?op_endName.
FILTER (regex(?op_endName, "Zele")).
?sol era:track ?track.
?track era:trackId ?trackId.
?track era:profileNumberSemiTrailers [skos:prefLabel ?profileNumberSemiTrailers].
} |
ds43 | If ETCS in operation, fill in parameters ETCS Baseline and ETCS Level, for tracks in a specific section of line. | PREFIX era: <http://data.europa.eu/949/>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
SELECT DISTINCT *
{
?sol a era:SectionOfLine .
?sol era:opStart ?op_start .
?op_start era:opName ?op_startName .
FILTER (regex(?op_startName, "Dendermonde")) .
?sol era:opEnd ?op_end .
?op_end era:opName ?op_endName .
FILTER (regex(?op_endName, "Zele")) .
?sol era:track ?track .
?track era:trackId ?trackId .
OPTIONAL { ?track era:highSpeedLoadModelCompliance "true"^^xsd:boolean } .
OPTIONAL { ?track era:etcsLevel ?etcsLevel . }
OPTIONAL {
?etcsLevelURI era:etcsBaseline [ skos:prefLabel ?etcsBaseline ] .
FILTER (uri(?etcsLevel) = ?etcsLevelURI)
}
OPTIONAL {
?etcsLevelURI era:etcsLevelType [ skos:prefLabel ?etcsLevelType ] .
FILTER (uri(?etcsLevel) = ?etcsLevelURI )
}
} |
ds44 | GSM-R version installed in tracks of a specific section of line. | PREFIX era: <http://data.europa.eu/949/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
SELECT DISTINCT *
{
?sol a era:SectionOfLine .
?sol era:opStart ?op_start .
?op_start era:opName ?op_startName .
FILTER (regex(?op_startName, "Dendermonde")) .
?sol era:opEnd ?op_end .
?op_end era:opName ?op_endName .
FILTER (regex(?op_endName, "Zele")) .
?sol era:track ?track .
?track era:trackId ?trackId .
?track era:gsmRVersion [ skos:prefLabel ?gsmRVersion ] .
} |
ds45 | Maximum Axle Load for tracks in a specific section of line (Note that this parameter does not exist. Therefore minAxleLoad is used, currently returns no values). | PREFIX era: <http://data.europa.eu/949/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
SELECT DISTINCT *
WHERE {
?sol a era:SectionOfLine .
?sol era:opStart ?op_start .
?op_start era:opName ?op_startName .
FILTER (regex(?op_startName, "Dendermonde")) .
?sol era:opEnd ?op_end .
?op_end era:opName ?op_endName .
FILTER (regex(?op_endName, "Zele")) .
?sol era:track ?track .
?track era:trackId ?trackId .
?track era:trainDetectionSystem ?trainDetSyst .
OPTIONAL {
?trainDetSyst era:tsdMinAxleLoadVehicleCategory ?tdsMinAxleLoadVehCat .
?tdsMinAxleLoadVehCat era:minAxleLoad ?minAxleLoad .
?tdsMinAxleLoadVehCat era:minAxleLoadVehicleCategory [ skos:prefLabel ?minAxleVehicleCategory ]
}
} |
ds46 | Nominal maximum operational speed on a specific section of line as a result of INF, ENE and CCS subsystem characteristics expressed in kilometres/hour. | PREFIX era: <http://data.europa.eu/949/>
SELECT DISTINCT *
{
?sol a era:SectionOfLine .
?sol era:opStart ?op_start .
?op_start era:opName ?op_startName .
FILTER (regex(?op_startName, "Dendermonde")) .
?sol era:opEnd ?op_end .
?op_end era:opName ?op_endName .
FILTER (regex(?op_endName, "Zele")) .
?sol era:track ?track .
?track era:trackId ?trackId .
?track era:maximumPermittedSpeed ?maximumPermittedSpeed
} |
Subsets and Splits
No community queries yet
The top public SQL queries from the community will appear here once available.